* Encoding: UTF-8.
***Script for Generating Absolute Wealth Estimate (AWE) from DHS Wealth Index

***Introduction:   This script is intended as a guide to those who would like to generate the
***                absolute wealth estimates (AWE) from DHS data, using the method described in:
***                Hruschka, D.J., Gerkey, D. & Hadley, C. 2015. "Estimating the Absolute Wealth of Households."
***                Bulletin of the World Health Organization. Article ID: BLT.147082


*** Data Requirements:   
***1. DHS data from one or more surveys.  Each survey represents a combination of a country and year.
***   Specifically, at least four variables are needed from the DHS Data:
***     A. Country ID.  Hereafter = "DHSCODE"
***     B. Year ID. Hereafter = "GDPYEAR"  (Each survey should have only one value for GDPYEAR)
***     C. DHS Wealth Factor Score.  Hereafter = "wealthfact"
***2. Country GDP per capita based on purchasing power parity (PPP) in constant 2011 international dollars.  Hereafter = "GDPpercapfinal2011"
***      Source: World Bank:  http://data.worldbank.org/indicator/NY.GDP.PCAP.PP.KD
***3. Country Gini Coefficient for household wealth.  Hereafter = "wealthgini2000"
***       Source: Davies, J.B., Sandstrom, S., Shorrocks, A.B., Wolff, E.N. 2009.
***               "The Level and Distribution of Global Household Wealth."
***               National Bureau of Economic Research Working Paper Series: Working Paper 15508
***               http://www.nber.org/papers/w15508
***               See Appendix V
***4. OilRents (% of GDP) .  Hereafter = "OilRentRecode"
***    Source: World Bank:  http://data.worldbank.org/indicator/NY.GDP.PETR.RT.Z
***5.  Household sampling weights. Hv005.

***Output
***lnwealthpercap5 is the final AWE estimate integrating Pareto estimates (lnwealthpercap2) & log-normal estimates (lnwealthpercap4).

***NOTE: The Hruschka et al. 2015 paper uses a specific formulation for deriving country level wealth per capita based on GDP and oil rents. 
***A researcher may choose a different method of calculating mean wealth per capita used in the formulas below (lnPPPwpc and PPPwpc)

SORT CASES  BY DHSCODE GDPYEAR.
SPLIT FILE LAYERED BY DHSCODE GDPYEAR.

delete variables wealthrank.
execute.

weight HV005.

RANK VARIABLES=wealthfact (A)
  /RFRACTION into wealthrank 
  /PRINT=NO
  /TIES=MEAN.

AGGREGATE
  /OUTFILE=* MODE=ADDVARIABLES OVERWRITE = YES
  /BREAK=DHSCODE GDPYEAR
  /NumObs=N.

***Ensures that proportional rank is less than one.

compute Rwealthn = wealthrank*(NumObs-1)/NumObs.
Execute.


compute wealthpareto_alpha2000 = (1+wealthgini2000)/(2*wealthgini2000).
execute.


compute countrywealthpercap=exp(1.129*ln(GDPpercapfinal2011*(1-oilrentrecode/100)) -0.293).
execute.

*calcuting wealth using pareto distribution*.


COMPUTE wealthpercap2=IDF.PARETO(Rwealthn,(1-1/Wealthpareto_alpha2000)*countrywealthpercap,Wealthpareto_alpha2000).
EXECUTE.

*calculating wealth using log-normal distribution*.

compute wealthlognormalsigma = sqrt(2)*probit((wealthgini2000+1)/2).
compute wealthlognormalmu = ln(countrywealthpercap) - wealthlognormalsigma*wealthlognormalsigma/2.

COMPUTE wealthpercap4=exp(IDF.NORMAL(Rwealthn,wealthlognormalmu,wealthlognormalsigma)).
EXECUTE.


AGGREGATE
  /OUTFILE=* MODE=ADDVARIABLES OVERWRITE = YES
  /BREAK=DHSCODE GDPYEAR
  /meanwealthpercap2=MEAN(wealthpercap2) 
  /meanwealthpercap4=MEAN(wealthpercap4) .

compute wealthpercap2 = wealthpercap2*countrywealthpercap/meanwealthpercap2.

compute wealthpercap4 = wealthpercap4*countrywealthpercap/meanwealthpercap4.
execute.


compute lnwealthpercap2 = ln(wealthpercap2).
execute.


compute lnwealthpercap4=ln(wealthpercap4).
execute.


compute lnwealthpercap5 =0.68*lnwealthpercap4+0.32*lnwealthpercap2.
compute wealthpercap5 = exp(lnwealthpercap5).
execute.

AGGREGATE
  /OUTFILE=* MODE=ADDVARIABLES OVERWRITE = YES
  /BREAK=DHSCODE GDPYEAR
  /meanwealthpercap5=MEAN(wealthpercap5) .

compute wealthpercap5 = wealthpercap5*countrywealthpercap/meanwealthpercap5.

execute.

weight off.